<!--
As in the license, Zymonic is provided without warranty or support
unless purchased separately, however... If you email
zymonic-support@zednax.com your issue will   be noted and may
receive a response.

For security issues, please contact zymonic-security@zednax.com and
someone will respond within 8 working hours.


=head1 AUTHOR

    Alex Masidlover et al.
    CPAN ID: MODAUTHOR
    Zednax Limited
    alex.masidlover@zednax.com
    http://www.zednax.com

=head1 COPYRIGHT

This program is free software licensed under the...

	Zymonic Public License 1.0

The full text of the license can be found in the
LICENSE file included with this module.

Other licenses may be acceptable if including
parts of Zymonic in larger projects, please
contact Zednax for details
-->
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema">
  
  <!-- field fill -->
  <xsl:template match="*[@type='FieldFillCalculation']">
    <!-- nothing to add to display, just setup JS objects -->
    <xsl:call-template name="SetupZymonicJSObject">
      <xsl:with-param name="type">FieldFillCalculation</xsl:with-param>
      <xsl:with-param name="object" select="."/>
      <xsl:with-param name="args">
        <xsl:call-template name="field_fill_calculation_js_params">
          <xsl:with-param name="ffc" select="." />
        </xsl:call-template>
      </xsl:with-param>
    </xsl:call-template>
    <!-- recalculate button -->
    <xsl:for-each select="RecalculateButton">
      <xsl:call-template name="jquery_submit_button">
        <xsl:with-param name="buttonId"    select="@ident"/>
        <xsl:with-param name="buttonName"  select="@ident"/>
        <xsl:with-param name="buttonValue" select="DisplayName"/>
        <xsl:with-param name="buttonClass">ZymonicFieldFillCalculationButton</xsl:with-param>
        <xsl:with-param name="TabIndex">0</xsl:with-param>
        <xsl:with-param name="BeforeOnClick"></xsl:with-param>
        
        <!-- click handler to be setup and done in the FieldFillCalculation JS objects -->
        <xsl:with-param name="no_js">true</xsl:with-param>
      </xsl:call-template>
    </xsl:for-each>
  </xsl:template>
  
  <!-- common params for field fill JS object -->
  <xsl:template name="field_fill_calculation_js_params">
    <xsl:param name="ffc"></xsl:param>
    parent_field: getZymonicField('<xsl:value-of select="$ffc/../@ident" />'),
    
    preffered: <xsl:value-of select="$ffc/@preffered" />,
    view_only:  <xsl:choose><xsl:when test="$ffc/ViewOnly='true'">true</xsl:when><xsl:otherwise>false</xsl:otherwise></xsl:choose>,
    cache_in_table: <xsl:choose><xsl:when test="$ffc/CacheInTable='true'">true</xsl:when><xsl:otherwise>false</xsl:otherwise></xsl:choose>,
    use_unless_user_value: <xsl:choose><xsl:when test="$ffc/UseUnlessUserValue='true'">true</xsl:when><xsl:otherwise>false</xsl:otherwise></xsl:choose>,
    allow_empty: <xsl:choose><xsl:when test="$ffc/AllowEmpty='true'">true</xsl:when><xsl:otherwise>false</xsl:otherwise></xsl:choose>,
    multiple_value_fill: <xsl:choose><xsl:when test="$ffc/MultipleValueFill='true'">true</xsl:when><xsl:otherwise>false</xsl:otherwise></xsl:choose>,
    <xsl:if test="$ffc/Condition">
    conditions: [
      <xsl:for-each select="$ffc/Condition">
        "<xsl:value-of select="." />",
      </xsl:for-each>
    ],
    condition_combination: "<xsl:value-of select="$ffc/ConditionCombination" />",
    </xsl:if>
    <xsl:if test="$ffc/Calculation">
    calculation: {
      string: "<xsl:value-of select="$ffc/Calculation/String" />",
      fields: [
        <xsl:for-each select="$ffc/Calculation/Field">
        {
          zname: "<xsl:value-of select="@zname" />",
          ident: "<xsl:value-of select="@ident" />",
        },
        </xsl:for-each>
      ]
    },
    </xsl:if>
    <xsl:if test="$ffc/StaticValue">
      static_value: "<xsl:value-of select="$ffc/StaticValue" />",
    </xsl:if>
    <xsl:if test="$ffc/FromOther">
    from_other: {
      use_display_value: <xsl:choose><xsl:when test="$ffc/FromOther/UseDisplayValue='true'">true</xsl:when><xsl:otherwise>false</xsl:otherwise></xsl:choose>,
      prefix_with_name: <xsl:choose><xsl:when test="$ffc/FromOther/PrefixWithName='true'">true</xsl:when><xsl:otherwise>false</xsl:otherwise></xsl:choose>,
      separator: "<xsl:value-of select="$ffc/Separator" />",
      fields: [
        <xsl:for-each select="$ffc/FromOther/Field">
        <xsl:sort select="@sequence" data-type="number" />
        {
          zname: "<xsl:value-of select="@zname" />",
          ident: "<xsl:value-of select="@ident" />",
          display_name: "<xsl:value-of select="DisplayName" />",
        },
        </xsl:for-each>
      ]
    },
    </xsl:if>
    
    <xsl:if test="$ffc/../JSFieldFillFormat">
    js_field_fill_format: '<xsl:value-of select="$ffc/../JSFieldFillFormat" />',
    </xsl:if>
    
    dependent_field_idents: [
      <xsl:for-each select="$ffc/DependentFieldIdent">
        "<xsl:value-of select="." />",
      </xsl:for-each>
    ],
    
    recalculate_buttons: [
      <xsl:for-each select="$ffc/RecalculateButton">
        {
          ident: "<xsl:value-of select="@ident" />",
          display_name: "<xsl:value-of select="DisplayName" />",
        },
      </xsl:for-each>
    ],
  </xsl:template>
  

</xsl:stylesheet>